変更ログ: 2.111.0

この2つのキーワードを隣接させずにauto ref パラメータを宣言することは非推奨となった。 こうすることで、ref とauto のセマンティクスを別々に記述するのではなく、auto ref のセマンティクスを意図していることが明確になる。 新しく導入されたref ローカル/グローバル変数については、直ちにエラーとなる。

void t()(ref const auto int x) // Deprecation
{
    ref auto y = x; // Error
}

// Correction:
void t()(auto ref const int x)
{
    auto ref y = x;
}

const(void)[] のデータにconst の末尾へのポインタが含まれている場合、 へのコピーは、 のデータに違反する可能性がある。void[] にコピーすると、const データに違反する可能性がある:

void f(int*[] a, const int*[] b)
{
    void[] va = a;
    const void[] vb = b;
    va[] = vb[]; // fills `a` with pointers to const
    *a[0] = 0; // const data mutated
}

vb のデータをva にコピーすることはできなくなった。 -preview=fixImmutableConv スイッチでは許可されなくなった。

align 、アライメントをその型のデフォルトに設定する。 あるいは、より明示的にalign(default) 。

struct S
{
    align(4)
    {
        byte x;
        align(default) long y;
        long z;
    }
}

void main()
{
    pragma(msg, S.x.alignof); // 4
    pragma(msg, S.y.alignof); // 8
    pragma(msg, S.z.alignof); // 4
}

以前は非推奨であったが、現在はエラーとなる:

int i;
switch (0)
{
    case 0, 1: i = 20;
    default: assert(0); // Error: switch case fallthrough - use 'goto default;' if intended
}

switch (0)
{
    default:
    case 0, 1: i = 20;
    case 2, 3: i = 30; // Error: switch case fallthrough - use 'goto case;' if intended
}

struct HasDtor
{
    ~this() {}
}

struct Pure
{
    HasDtor member;
    this(int) pure {} // Error: `this` has stricter attributes than its destructor (`pure`)
}

struct Nothrow
{
    HasDtor member;
    this(int) nothrow {} // Error: `this` has stricter attributes than its destructor (`nothrow`)
}

struct NoGC
{
    HasDtor member;
    this(int) @nogc {} // Error: `this` has stricter attributes than its destructor (`@nogc`)
}

struct Safe
{
    HasDtor member;
    this(int) @safe {} // Error: `this` has stricter attributes than its destructor (`@safe`)
}

これは以前は非推奨であったが、現在はエラーである:

void test() nothrow
in
{
    throw new Exception(null); // Error: `in` contract may throw but function is marked as `nothrow`
}
out
{
    throw new Exception(null); // Error: `out` contract may throw but function is marked as `nothrow`
}
do
{
}

これにより、== 演算子を使用した一部の構造体比較に影響するバグが修正された。 詳細については、2.085.0 の-preview=fieldwise のエントリーを参照のこと。 のエントリーを参照のこと。

新しい-revert=fieldwise スイッチは、バグフィックスを無効にし、元の動作に戻すために使うことができる。 元の== 。

LDCコンパイラがすでに持っている-ftime-trace スイッチがdmdでも使えるようになった。 これを使えば、コードのどの部分のコンパイルに一番時間がかかるかを知ることができ、ビルド時間を最適化できる。

dmd -ftime-trace app.d

これはapp.o.time-trace を出力する。

別の出力ファイルは-ftime-trace-file=trace.json で選択できる。

出力はGoogle Chromeのプロファイラフォーマットで、ui.perfetto.devのようなインタラクティブなビューアで見ることができる。

YouTubeのチュートリアルも参照のこと:Dコンパイラのプロファイリングでビルド時間を短縮する

これでビルトイン・ビットフィールドのイントロスペクション機能が完成した。例:」:

struct S
{
    int a,b;
    int :2, c:3;
}

static assert(__traits(getBitfieldOffset, S.b) == 0);
static assert(__traits(getBitfieldOffset, S.c) == 2);
static assert(__traits(getBitfieldWidth, S.b) == 32);
static assert(__traits(getBitfieldWidth, S.c) == 3);

以前は.cソースファイルを手動でインクルードする必要があったが、.dファイルと同様に動作するようになった。

Import式は string 、バイナリファイルの埋め込みにも使用される。 16進文字列と同じように扱うことで、char 以外の積分型の配列に暗黙的に変換される。

// Formerly, a cast was required:
immutable ubyte[] iconImg = cast(immutable ubyte[]) import("icon.png");

// Now, it implicitly converts to integral arrays:
immutable ubyte[] iconImg = import("icon.png");

ImportCの新しいプラグマで、関数宣言のデフォルト・ストレージ・クラスを設定できる。 クラスを設定することができる:

#pragma attribute(push, [storage classes...])

nothrow 、nogc 、pure がサポートされている。 認識されない属性は無視される。 デフォルトのストレージ・クラスを有効にすると、他のプラグマで無効化されるま で、プラグマ以降のすべての関数宣言に影響する。 の後にあるすべての関数宣言に影響する。 インクルード内の宣言も影響を受ける。次の例:」。 ライブラリの@nogc とnothrow を有効にする:

#pragma attribute(push, nogc, nothrow)
#include <somelibrary.h>

変更されたストレージクラスはスタックにプッシュされる。最後の変更は 以下のプラグマで取り消すことができる:

#pragma attribute(pop)

これは、複数のデフォルト・ストレージ・クラスを同時に無効にすることもできる、 #pragma attribute(push, ...) を同時に無効にすることもできる。

COM クラスは、IUnknown と呼ばれるユーザー定義インタフェースを継承する。 コンパイル時にこれを検出するには、__traits(isCOMClass, Type) を使用する。 また、実行時にはTypeInfo_Class フラグを使用する。

以前は、ミックスイン・テンプレート・インスタンスに名前をつけるには、名前を最後につける必要があった。 今は、代入構文を使ってインスタンスの前に置くこともできる。

mixin MyMixinTemplate!(Args) myName; // old style
mixin myName = MyMixinTemplate!(Args); // new style

さらに、Objective-Cセレクタの生成ルールが変更され、以下の手順に従うようになった:

1. "@property "の付いた関数は、セッターにsetXYZ: 。
2. "is "という接頭辞が付いたプロパティ関数では、セッターでis 。
3. セレクタの生成では、Dマングルされた型ではなく、関数のパラメータ名を使用するようになった。

セレクタはまだ@selector UDAで指定することができる。 で指定することもできる。

これらの新しいルールは、外部および非外部のobjective-cクラスとプロトコルの両方に適用される。

extern(Objective-C)
extern class NSObject {
    static NSObject alloc(); // Generates as `alloc`
    NSObject init(); // Generates as `init`
}

extern(Objective-C)
class Fox : NSObject {
    bool fluffy;

    @property bool isFluffy() => fluffy; // `isFluffy`
    @property void isFluffy(bool value) { fluffy = value; } // `setFluffy:`

    void yip(int a) @selector("bark:") { // `bark:`
        // ...
    }

    void doSomething(int a, int b, int c) { // `doSomething:b:c:`
        // ...
    }
}

セレクタの自動生成は以前にはなかったので、これらの変更によって既存のコードが壊れることはないはずだ。 は以前には存在しなかったからだ。また、セレクタの自動生成はextern(Objective-C)メソッドにのみ適用される。

-od このスイッチは、オブジェクト・ファイルに完全修飾名を与える。 を使ったときの名前の衝突を防ぐ。 このスイッチはすでにLDCに存在していたが、dmdにも追加された。

例:」:

dmd -c -oq -od=. app.d util/app.d misc/app.d

これにより、app.obj ではなく、app.obj 、util.app.obj 、misc.app.obj が出力される。

-oq また、DDoc ( ) や .di ヘッダー生成 ( ) などの他の出力にも適用される。 -D -Dd=.-H -Hd=.

.di インターフェイスファイル生成とDdoc出力で、メソッド(とコンストラクタ)のパラメータリストの後に型修飾子属性が置かれるようになった。 属性を持つようになった。 これにより、戻り値の型との混乱を避けることができる。

struct S
{
    const int f(); // before
    int f() const; // now
}

例えば、次のように書くことができる:

struct S { int a; }

void main()
{
    S s;
    ref int r = s.a;
    r = 3;
    assert(s.a == 3);

    auto ref x = 0;
    auto ref y = x;
    static assert(!__traits(isRef, x));
    static assert( __traits(isRef, y));
}

ref のオーバーロード:

foo(S s); // selected if `s` is an rvalue
foo(ref S s); // selected if argument `s` is an lvalue

S s;
S bar();
...
foo(s); // selects foo(ref S)
foo(bar()); // selects foo(S)

この変更に伴い、このようになった、

foo(__rvalue(s)); // selects foo(S)

これはコンストラクターや代入にも適用される。 移動代入が有効になる。コピーの代わりに移動させることで、リソース効率が向上する。 例えば、文字列をコピー/削除するよりも移動させる方がはるかにリソース効率がよい。

移動したオブジェクトは破壊される可能性がある。 フィールドを移動させるときは、そのことを考慮して、破壊可能な穏やかな値に設定する。

現在@safe のコードで有効になっているチェックのうち、修正が容易なもの(修正が関数に限定されているもの)はすべて のコードで有効になる。 修正が関数に制約される)、現在-preview=safer 。

@system 、あるいは無属性関数の呼び出しのような、修正が容易でないコードは、従来通り許可される。 は従来通り許される。

void f();
@system void g();

void main()
{
    int* p;
    p++; // Error, pointer arithmetic
    f(); // allowed
    g(); // allowed
}

詳細はsafer.mdを参照のこと。

以前は「コンストラクターから式を返すことができない」というエラーが発生していたが、現在はサポートされている:

struct Number
{
    int x;

    void vf(int);
    this(int x) => vf(x);
    this(float x) => this(cast(int) x);
}

式本体は、this/super 呼び出しであるか、void 型でなければならない。

ポストブリットとデストラクタは、void を返すので、すでに短縮メソッド構文をサポートしている。

仕様が更新された (2.109用に)更新された。 のみが安全な値である。 boolである。これは、bool の値を読み取る場合、そのバイト表現に他のビットが設定されていることを意味する。 の読み取りは処理系定義であり、避けるべきである。 その結果、@safe のコードでは、以下が非推奨となる:

• void ブール値の初期化(2.109以降)
• 共用体からbool フィールドを読み込む(2.109以降)。
• 動的配列をbool 動的配列型にキャストする実行時。
• bool 、動的配列を末尾の変更可能な動的配列型にキャストする。
• ポインタのbool ポインタ型へのキャスト
• bool ポインタを末尾の変更可能ポインタ型にキャストする

criticalRegionLock機能には重大な設計上の欠陥がある。https://issues.dlang.org/show_bug.cgi?id=24741

使用されないことが判明したため、欠陥を修正するのではなく、機能を削除した。

LDC/GDCコンパイラ用の分岐と値のヒントのための関数expect とlikely/unlikely を追加する。 DMDはこれらのヒントを無視する。

ターゲットに依存するトラップ命令に、trap を追加する。 ターゲットにトラップ命令がない場合、この組込み関数はabort() 関数の呼び出しに lowered される。

formattedReadにテンプレート引数型を渡すことができるようになった。 フォーマット文字列とともにformattedReadに渡すことができるようになった。 すべての引数の読み込みに成功しなければならない。 と異なり、std.format.FormatExceptionがスローされる。

import std.exception : assertThrown;
import std.format : FormatException;
import std.typecons : tuple;

@safe pure unittest
{
    auto complete = "hello!34.5:124".formattedRead!(string, double, int)("%s!%s:%s");
    assert(complete == tuple("hello", 34.5, 124));

    assertThrown!FormatException("hello!34.5:".formattedRead!(string, double, int)("%s!%s:%s"));
}

/// The format string can be checked at compile-time:
@safe pure unittest
{
    auto expected = tuple("hello", 124, 34.5);
    auto result = "hello!124:34.5".formattedRead!("%s!%s:%s", string, int, double);
    assert(result == expected);

    assertThrown!FormatException("hello!34.5:".formattedRead!("%s!%s:%s", string, double, int));
}

この新しい関数は、16進文字列からバイト範囲への変換を可能にする。 テンプレート std.conv.hexStringテンプレートとは異なり この関数はランタイム入力で使用できる。

std.conv モジュールには、入力を直接バイト列に変換する便利な機能がない。 をバイト列に直接変換する機能がない。どちらも std.conv.parseと std.conv.toは、要求されたターゲット整数型の単一の値に対する変換しか扱えない。 変換しか扱えない。さらに、これらの関数は結果のために新しいバッファを割り当てる。 fromHexStringAsRange のために新しいバッファを割り当てる。 を実装することで遅延的に動作する。

さらに便利なことに、検証関数がある。 std.digest.isHexString も追加された。

新しい関数は既存の std.uni.graphemeStrideと std.uni.decodeGrapheme関数を掛け合わせたものである。新関数では、以下の両方がサポートされる。 がgraphemeStride のように@safe pure nothrow @nogc をサポートする。 自動デコードに頼らない限り、@nogc のように をサポートする。graphemeStride のサポートが追加された)。 decodeGrapheme のように、配列以外の範囲でも動作する。

例:」:

import std.uni;

// Two Union Jacks of the Great Britain in each
string s = "\U0001F1EC\U0001F1E7\U0001F1EC\U0001F1E7";
wstring ws = "\U0001F1EC\U0001F1E7\U0001F1EC\U0001F1E7";
dstring ds = "\U0001F1EC\U0001F1E7\U0001F1EC\U0001F1E7";

// String pop length in code units, not points.
assert(s.popGrapheme() == 8);
assert(ws.popGrapheme() == 4);
assert(ds.popGrapheme() == 2);

assert(s == "\U0001F1EC\U0001F1E7");
assert(ws == "\U0001F1EC\U0001F1E7");
assert(ds == "\U0001F1EC\U0001F1E7");

import std.algorithm.comparison : equal;
import std.algorithm.iteration : filter;

// Also works for non-random access ranges as long as the
// character type is 32-bit.
auto testPiece = "\r\nhello!"d.filter!(x => !x.isAlpha);
// Windows-style line ending is two code point in a single grapheme.
assert(testPiece.popGrapheme() == 2);
assert(testPiece.equal("!"d));

新しい std.experimental.allocator.building_blocks.allocator_list.SharedAllocatorListは、通常のAllocatorList と同じセマンティクスを持つ。 通常のAllocatorList と同様に、BookkeepingAllocator がNullAllocator の場合、SharedAllocatorList はouroboros モードに切り替わる、 自分自身のメタデータのためにメモリを割り当てる。

SharedAllocatorList!((n) => SharedAscendingPageAllocator(max(n, numPages * pageSize)), NullAllocator) a;
auto b = a.allocate(100);
assert(b.length == 100);

assert(a.deallocate(b));

このUnicodeアップデートは2024年9月10日にリリースされ、新しい文字ブロックが追加された。 参照:https://www.unicode.org/versions/Unicode16.0.0/

import std;

void main()
{
    const alphaCount = iota(0, dchar.max).filter!(std.uni.isAlpha).walkLength;
    writeln(alphaCount);
    // formerly: 138387
    // now:      142759
}

パッケージのルートディレクトリにdub.selections.json ファイルがない場合、dubは親ディレクトリも探すようになり、最初に見つかった(最も深い)ファイルを使う可能性がある。 を使用する可能性がある。 "inheritable": true フラグが含まれている場合に限る。

これにより、複数のダビングプロジェクトを含むリポジトリに「中央」dub.selections.json ファイルを使用することができる。 ファイルを使うことができる。 リポジトリルートディレクトリにある場合、そのソースツリー内のすべてのビルドに自動的に適用される。 (ローカルのdub.selections.json がそれを上書きしない限り)。

このような継承されたセレクトファイルは、ネストしたプロジェクトでダブを実行しても、決して変更されることはない。 つまり、変更は常にローカルに保存される。 dub.selections.json ファイルに保存される。例えば、dub upgrade をネストされたプロジェクトに対して実行した場合。 プロジェクトに対して