std.format

FormatString:
    FormatStringItem FormatString
FormatStringItem:
    Character
    FormatSpecifier
FormatSpecifier:
    '%' Parameters FormatIndicator


FormatIndicator:
    FormatCharacter
    CompoundIndicator
FormatCharacter:
    see remark below
CompoundIndicator:
    '(' FormatString '%)'
    '(' FormatString '%|' Delimiter '%)'
Delimiter
    empty
    Character Delimiter


Parameters:
    Position Flags Width Precision Separator
Position:
    empty
    Integer '$'
    Integer ':' Integer '$'
    Integer ':' '$'
Flags:
    empty
    Flag Flags
Flag:
    '-'|'+'|' '|'0'|'#'|'='
Width:
    OptionalPositionalInteger
Precision:
    empty
    '.' OptionalPositionalInteger
Separator:
    empty
    ',' OptionalInteger
    ',' OptionalInteger '?'
OptionalInteger:
    empty
    Integer
    '*'
OptionalPositionalInteger:
    OptionalInteger
    '*' Integer '$'


Character
    '%%'
    AnyCharacterExceptPercent
Integer:
    NonZeroDigit Digits
Digits:
    empty
    Digit Digits
NonZeroDigit:
    '1'|'2'|'3'|'4'|'5'|'6'|'7'|'8'|'9'
Digit:
    '0'|'1'|'2'|'3'|'4'|'5'|'6'|'7'|'8'|'9'

// 最も簡単な方法は、どこでも`%s`を使うことである:
// "I got 30 eggs for 5.27 euros."("卵30個を5.27ユーロで買った。")
writeln(format("I got %s %s for %s euros.", 30, "eggs", 5.27));

// 他の書式文字では、もっとコントロールできる:
// "I got 11110 65676773 for 5.270000 euros."("5.270000ユーロで11110 65676773を手に入れた")
writeln(format("I got %b %(%X%) for %f euros.", 30, "eggs", 5.27));

/*
各項目の指定子に続くサブフォーマット文字列の末尾は、
配列の区切り文字として解釈されるため、
配列の最後の項目以降は省略される:
 */
    writeln(format("My items are %(%s %).", [1, 2, 3])); // "My items are 1 2 3."
    writeln(format("My items are %(%s, %).", [1, 2, 3])); // "My items are 1, 2, 3."

/*
区切り文字"%|"指定子は、
区切り文字がどこで始まるかを示すために使用することができ、
その場合、区切り文字より前のフォーマット文字列の部分は、最後の配列要素に保持される:
 */
    writeln(format("My items are %(-%s-%|, %).", [1, 2, 3])); // "My items are -1-, -2-, -3-."

/*
これらの複合書式指定子は、入れ子配列引数の場合、
入れ子にすることができる:
 */
    auto mat = [[1, 2, 3],
                [4, 5, 6],
                [7, 8, 9]];

    assert(format("%(%(%d %) - %)", mat), "1 2 3 - 4 5 6 - 7 8 9");
    assert(format("[%(%(%d %) - %)]", mat), "[1 2 3 - 4 5 6 - 7 8 9]");
    assert(format("[%([%(%d %)]%| - %)]", mat), "[1 2 3] - [4 5 6] - [7 8 9]");

/*
複合書式指定子の内部では、文字列と文字が自動的にエスケープされる。
この動作を避けるには、"%("の代わりに"%-("を使用する:
 */
    // `My friends are ["John", "Nancy"].`
    writeln(format("My friends are %s.", ["John", "Nancy"]));
    // `My friends are "John", "Nancy".`
    writeln(format("My friends are %(%s, %).", ["John", "Nancy"]));
    // `My friends are John, Nancy.`
    writeln(format("My friends are %-(%s, %).", ["John", "Nancy"]));

// Flagsは結果に影響を与えるために使うことができる:
writeln(format("%g != %+#g", 3.14, 3.14)); // "3.14 != +3.14000"

// 幅と精度は、フォーマットされた結果を整えるのに役立つ:
writeln(format(">%10.2f<", 1234.56789)); // ">   1234.57<"

// 数字はグループ化できる:
writeln(format("%,4d", int.max)); // "21,4748,3647"

// 引数の位置を指定することも可能だ:
writeln(format("%3$s %1$s", 3, 17, 5)); // "5 3"

// 引数としての幅
writeln(format(">%*s<", 10, "abc")); // ">       abc<"

// 引数としての精度
writeln(format(">%.*f<", 5, 123.2)); // ">123.20000<"

// 引数としてのグループ化
writeln(format("%,*d", 1, int.max)); // "2,1,4,7,4,8,3,6,4,7"

// グループ分けのセパレーターを引数に取る
writeln(format("%,3?d", '_', int.max)); // "2_147_483_647"

// 一気に
writeln(format("%*.*,*?d", 20, 15, 6, '/', int.max)); // "   000/002147/483647"

class FormatException: object.Exception;

フォーマット中に問題が発生したことを示す。

Examples:

import std.exception : assertThrown;

assertThrown!FormatException(format("%d", "foo"));

pure nothrow @nogc @safe this();

汎用コンストラクタ。

pure nothrow @nogc @safe this(string msg, string fn = __FILE__, size_t ln = __LINE__, Throwable next = null);

FormatException の新しいインスタンスを作成する。

Parameters:

string msg	例外のメッセージ
string fn	例外が発生したファイルのファイル名 (オプション)
size_t ln	例外が発生したファイルの行番号 (オプション)
Throwable next	内部使用のため、常にNULLでなければならない (オプション)

immutable(Char)[] format(Char, Args...)(in Char[] fmt, Args args)
if (isSomeChar!Char);

typeof(fmt) format(alias fmt, Args...)(Args args)
if (isSomeString!(typeof(fmt)));

フォーマット文字列に従って引数を文字列に変換する。

2番目のバージョンの formatの第2バージョンは、フォーマット文字列をテンプレート 引数として受け取る。この場合、コンパイル時に整合性がチェックされる。 この場合、コンパイル時に整合性がチェックされ、出力バッファの長さを事前に推定できるため、若干高速なコードが生成される。 出力バッファの長さを事前に見積もることができるからだ。

Parameters:

Char[] fmt	フォーマット文字列
Args args	フォーマットされる引数の可変長引数リスト
Char	文字型 fmt
Args	引数の可変長引数リスト

Returns:

フォーマットされた文字列。

Throws:

A FormatExceptionフォーマットが成功しなかった場合

See Also:

sformatガベージコレクションを回避しようとする変種である。

Examples:

writeln(format("Here are %d %s.", 3, "apples")); // "Here are 3 apples."("ここに3個のリンゴがある。")

writeln("Increase: %7.2f %%".format(17.4285)); // "Increase:   17.43 %"

Examples:

フォーマット文字列はコンパイル時にチェックできる:

auto s = format!"%s is %s"("Pi", 3.14);
writeln(s); // "Pi is 3.14"

// 3.14は%dでフォーマットできないので、この行はコンパイルされない:
// s = format!"%s is %d"("Pi", 3.14);

char[] sformat(Char, Args...)(return scope char[] buf, scope const(Char)[] fmt, Args args);

char[] sformat(alias fmt, Args...)(char[] buf, Args args)
if (isSomeString!(typeof(fmt)));

フォーマット文字列に従って引数をバッファに変換する。 バッファは、フォーマットされた文字列を保持するのに十分な大きさでなければならない。

番目のバージョンの sformatの第2バージョンは、フォーマット文字列をテンプレート 引数として受け取る。この場合、コンパイル時に整合性がチェックされる。 コンパイル時にチェックされる。

Parameters:

char[] buf	フォーマットされた文字列が入るべきバッファ
const(Char)[] fmt	フォーマット文字列
Args args	フォーマットされる引数の可変長引数リスト
Char	文字型 fmt
Args	引数の可変長引数リスト

Returns:

のスライス。 bufのスライス。

Throws:

以下の場合、RangeErrorとなる。 buf フォーマットされた文字列を保持するのに十分な大きさがない場合 を、そして FormatExceptionを返す。

注釈:理論的には、この関数は であるべきである。 理論的には、この関数は@nogc 。しかし、現在の の実装では、アロケーションが発生するケースがある:

• 例外がスローされる。
• 複合型のカスタム関数(toString )がアロケートする。

Examples:

char[20] buf;
writeln(sformat(buf[], "Here are %d %s.", 3, "apples")); // "Here are 3 apples."("ここに3個のリンゴがある。")

writeln(buf[].sformat("Increase: %7.2f %%", 17.4285)); // "Increase:   17.43 %"

Examples:

フォーマット文字列はコンパイル時にチェックできる:

char[20] buf;

writeln(sformat!"Here are %d %s."(buf[], 3, "apples")); // "Here are 3 apples."("ここに3個のリンゴがある。")

// 3.14は%dでフォーマットできないので、この行はコンパイルされない:
// writeln(sformat!"Here are %d %s."(buf[], 3.14, "apples"));